diff --git a/modules/system/homelab/mc/mc0-vanilla-plus.nix b/modules/system/homelab/mc/mc0-vanilla-plus.nix
index 79f86bc..5240835 100644
--- a/modules/system/homelab/mc/mc0-vanilla-plus.nix
+++ b/modules/system/homelab/mc/mc0-vanilla-plus.nix
@@ -3,6 +3,11 @@
   ram-allocation-mb = 8192;
   headroom-allocation-mb = 1024;
   rcon-pass = "howdy";
+  ports = {
+    minecraft = 25565;
+    rcon = 25575;
+  };
+  
   modpack = let
     useLatest = false;
     commit = "86bf13316ed1352a676d9056d284448ea5e5a079";
@@ -18,13 +23,13 @@ in {
   };
   
   services.minecraft-servers.servers.${name} = {
-    enable = true;
+    enable = false;
     autoStart = true;
     restart = "always";
     
     serverProperties = {
       server-ip = "0.0.0.0";
-      server-port = 25565;
+      server-port = ports.minecraft;
       server-name = name;
       motd = "§cCan't connect to server";
       log-ips = false;
@@ -49,7 +54,7 @@ in {
       enable-rcon = true;
       sync-chunk-writes = false;
       "rcon.password" = rcon-pass;
-      "rcon.port" = 25575;
+      "rcon.port" = ports.rcon;
     };
     
     symlinks = inputs.mc.lib.collectFilesAt modpack "mods" // {
diff --git a/modules/system/homelab/mc/mc1-pure-vanilla.nix b/modules/system/homelab/mc/mc1-pure-vanilla.nix
index 6b64a85..9268e35 100644
--- a/modules/system/homelab/mc/mc1-pure-vanilla.nix
+++ b/modules/system/homelab/mc/mc1-pure-vanilla.nix
@@ -3,6 +3,10 @@
   ram-allocation-mb = 8192;
   headroom-allocation-mb = 1024;
   rcon-pass = "howdy";
+  ports = {
+    minecraft = 25566;
+    rcon = 25576;
+  };
   
   modpack = pkgs.fetchModrinthModpack {
     url = "https://cdn.modrinth.com/data/2wkV8mHp/versions/mFGJP1Ye/Server%20Optimization%201.21.11-2.1.mrpack";
@@ -17,7 +21,7 @@ in {
     
     serverProperties = {
       server-ip = "0.0.0.0";
-      server-port = 25566;
+      server-port = ports.minecraft;
       server-name = name;
       motd = "§cCan't connect to server";
       log-ips = false;
@@ -42,7 +46,7 @@ in {
       enable-rcon = true;
       sync-chunk-writes = false;
       "rcon.password" = rcon-pass;
-      "rcon.port" = 25576;
+      "rcon.port" = ports.rcon;
     };
     
     files = inputs.mc.lib.collectFilesAt modpack "config";
diff --git a/modules/system/homelab/mc/mc2-create-aeronautics.nix b/modules/system/homelab/mc/mc2-create-aeronautics.nix
new file mode 100644
index 0000000..0e557c7
--- /dev/null
+++ b/modules/system/homelab/mc/mc2-create-aeronautics.nix
@@ -0,0 +1,120 @@
+{ inputs, lib, pkgs, ... }: let
+  name = "mc2-create-aeronautics";
+  ram-allocation-mb = 12288;
+  headroom-allocation-mb = 2048;
+  rcon-pass = "howdy";
+  ports = {
+    minecraft = 25567;
+    rcon = 25577;
+  };
+  
+  modpack = let
+    useLatest = true;
+    commit = "";
+    path = if !useLatest then "commit/${commit}" else "branch/main";
+  in pkgs.fetchPackwizModpack {
+    packHash = "";
+    url = "https://git.satr14.my.id/satr14/create-modpack/raw/${path}/pack.toml";
+  };
+in {
+  systemd.services."minecraft-server-${name}" = {
+    environment.LD_LIBRARY_PATH = "${pkgs.stdenv.cc.cc.lib}/lib"; # physics toys mod fix
+    # serviceConfig.Nice = -5; # higher scheduling priority (causes fan noise even when idle)
+  };
+  
+  services.minecraft-servers.servers.${name} = {
+    enable = true;
+    autoStart = true;
+    restart = "always";
+    
+    serverProperties = {
+      server-ip = "0.0.0.0";
+      server-port = ports.minecraft;
+      server-name = name;
+      motd = "§cCan't connect to server";
+      log-ips = false;
+      hide-online-players = true; 
+      
+      difficulty = "normal";
+      gamemode = "survival";
+      max-world-size = 25000;
+      spawn-protection = 0;
+      pvp = true;
+      
+      online-mode = true;
+      enable-query = true;
+      enforce-secure-profile = false;
+      pevent-proxy-connections = false;
+      allow-flight = false;
+      player-idle-timeout = 0;
+      
+      view-distance = 12;
+      simulation-distance = 6;
+      
+      enable-rcon = true;
+      sync-chunk-writes = false;
+      "rcon.password" = rcon-pass;
+      "rcon.port" = ports.rcon;
+    };
+    
+    symlinks = inputs.mc.lib.collectFilesAt modpack "mods" // {
+      "polymer/packsquash" = let packsquash-binary = pkgs.runCommand "packsquash" {
+        src = pkgs.fetchurl {
+          url = "https://github.com/ComunidadAylas/PackSquash/releases/download/v0.4.1/packsquash-x86_64-unknown-linux-gnu.zip";
+          sha256 = "sha256-VsGZewoiO5MjhIhwjlLO5d5uHynlAK5Jh16jH2k2rPs=";
+        };
+        nativeBuildInputs = [ pkgs.unzip ];
+      } ''
+        mkdir -p $out/bin
+        unzip $src -d $out/bin
+        chmod +x $out/bin/packsquash
+      ''; in "${packsquash-binary}/bin/packsquash";
+    };
+
+    files = inputs.mc.lib.collectFilesAt modpack "config" // {
+      "config/proxy_protocol_support.json".value = {
+        enableProxyProtocol = false; # polymer auto host has issues with proxy protocol
+        whitelistTCPShieldServers = false;
+        proxyServerIPs = [ "127.0.0.1" "::1" ];
+        directAccessIPs = [ "127.0.0.0/8" "::1/128" ];
+      };
+    };
+    
+    extraStartPre = let sed-commands = lib.concatStringsSep "\n" (
+      lib.mapAttrsToList (substitution: file: 
+        ''sed -i "s|${substitution}|''${${substitution}}|g" ${file}''
+      ) {
+        "REPLACE_SVC_HOST"      = "config/voicechat/voicechat-server.properties";
+        "REPLACE_RP_LINK"       = "config/welcomemessage.json5";
+        "REPLACE_DC_BOT_TOKEN"  = "config/simple-discord-link/simple-discord-link.toml";
+        "REPLACE_DC_OWNER_ROLE" = "config/simple-discord-link/simple-discord-link.toml";
+      }
+    ); in ''
+      # shellcheck disable=SC1091
+      if [ -f modpack-config.env ]; then
+        source modpack-config.env
+        ${sed-commands}
+      fi
+    '';
+    
+    package = pkgs.fabricServers.fabric-1_21_11.override {
+      jre_headless = pkgs.javaPackages.compiler.temurin-bin.jdk-25;
+      loaderVersion = "0.19.2";
+    };
+
+    jvmOpts = let flags = [
+      "-Xms${toString ram-allocation-mb}M"
+      "-Xmx${toString ram-allocation-mb}M"
+      
+      "-XX:+UseZGC" # Use ZGC (requires Java v25+, 8+ CPU cores, 10GB+ RAM)
+      "-XX:+ZGenerational" # Use generational ZGC (newer and better ZGC, requires Java v21+)
+      "-XX:+UseCompactObjectHeaders" # Use compact object headers (requires Java v16+, saves a couple of bits per object)
+      
+      "--add-modules=jdk.incubator.vector" # Exposes SIMD instructions (requires full JDK, useful with performance mods like C2ME)
+      "-XX:+AlwaysPreTouch" # Pre-allocates memory on startup, OS claims it immediately for JVM instead of negotiating it
+      "-XX:+DisableExplicitGC" # Disables mods from manually invoking the GC
+      "-XX:+PerfDisableSharedMem" # Disables constant /tmp writes for JVM metrics
+      "-XX:SoftMaxHeapSize=${toString (ram-allocation-mb - headroom-allocation-mb)}M" # Leave 2GB headroom
+    ]; in lib.concatStringsSep " " flags;
+  };
+}
\ No newline at end of file